---

ВЫБРАТЬ
	ДокОтборТовары.Номенклатура КАК Номенклатура,
	ДокОтборТовары.Ячейка КАК Ячейка,
	СУММА(ДокОтборТовары.КоличествоУпаковок - ДокОтборТовары.КоличествоУпаковокОтобрано) КАК КоличествоОтобрано
ПОМЕСТИТЬ ВТОтборПоЯчейкам
ИЗ
	Документ.ОтборРазмещениеТоваров.ТоварыОтбор КАК ДокОтборТовары
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ОтборРазмещениеТоваров КАК ДокОтбор
		ПО ДокОтборТовары.Ссылка = ДокОтбор.Ссылка
			И ДокОтбор.Проведен
			И (ДокОтбор.Склад = &Склад
				ИЛИ &Склад = ЗНАЧЕНИЕ(Справочник.Склады.ПустаяСсылка))
			И ДокОтбор.Статус В (ЗНАЧЕНИЕ(Перечисление.СтатусыОтборовРазмещенийТоваров.ВРаботе), ЗНАЧЕНИЕ(Перечисление.СтатусыОтборовРазмещенийТоваров.Подготовлено))

СГРУППИРОВАТЬ ПО
	ДокОтборТовары.Номенклатура,
	ДокОтборТовары.Ячейка

ИМЕЮЩИЕ
	СУММА(ДокОтборТовары.КоличествоУпаковок - ДокОтборТовары.КоличествоУпаковокОтобрано) > 0

ИНДЕКСИРОВАТЬ ПО
	Номенклатура,
	Ячейка
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТОтборПоЯчейкам.Номенклатура КАК Номенклатура,
	СУММА(ВТОтборПоЯчейкам.КоличествоОтобрано) КАК КоличествоОтобраноОбщее
ПОМЕСТИТЬ ВТОтборПоТовару
ИЗ
	ВТОтборПоЯчейкам КАК ВТОтборПоЯчейкам

СГРУППИРОВАТЬ ПО
	ВТОтборПоЯчейкам.Номенклатура

ИНДЕКСИРОВАТЬ ПО
	Номенклатура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ОстаткиТовара.Номенклатура КАК Номенклатура,
	СУММА(ОстаткиТовара.Количество) КАК КоличествоОбщее
ПОМЕСТИТЬ ВТОстаткиПоТовару
ИЗ
	РегистрСведений.ТоварыВЯчейках КАК ОстаткиТовара
ГДЕ
	(ОстаткиТовара.Склад = &Склад
		ИЛИ &Склад = ЗНАЧЕНИЕ(Справочник.Склады.ПустаяСсылка))

СГРУППИРОВАТЬ ПО
	ОстаткиТовара.Номенклатура

ИНДЕКСИРОВАТЬ ПО
	Номенклатура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	РегистрСведенийТоварыВЯчейках.Номенклатура КАК Номенклатура,
	РегистрСведенийТоварыВЯчейках.Ячейка КАК Ячейка,
	РегистрСведенийТоварыВЯчейках.Номенклатура.Артикул КАК Артикул,
	РегистрСведенийТоварыВЯчейках.Количество КАК Количество,
	ЕСТЬNULL(ВТОстаткиПоТовару.КоличествоОбщее, 0) КАК КоличествоОбщее,
	ЕСТЬNULL(ВТОтборПоЯчейкам.КоличествоОтобрано, 0) КАК КоличествоОтобрано,
	ЕСТЬNULL(ВТОтборПоТовару.КоличествоОтобраноОбщее, 0) КАК КоличествоОтобраноОбщее
ИЗ
	РегистрСведений.ТоварыВЯчейках КАК РегистрСведенийТоварыВЯчейках
		ЛЕВОЕ СОЕДИНЕНИЕ ВТОтборПоЯчейкам КАК ВТОтборПоЯчейкам
		ПО РегистрСведенийТоварыВЯчейках.Номенклатура = ВТОтборПоЯчейкам.Номенклатура
			И РегистрСведенийТоварыВЯчейках.Ячейка = ВТОтборПоЯчейкам.Ячейка
		ЛЕВОЕ СОЕДИНЕНИЕ ВТОстаткиПоТовару КАК ВТОстаткиПоТовару
		ПО РегистрСведенийТоварыВЯчейках.Номенклатура = ВТОстаткиПоТовару.Номенклатура
		ЛЕВОЕ СОЕДИНЕНИЕ ВТОтборПоТовару КАК ВТОтборПоТовару
		ПО РегистрСведенийТоварыВЯчейках.Номенклатура = ВТОтборПоТовару.Номенклатура
ГДЕ
	(РегистрСведенийТоварыВЯчейках.Склад = &Склад
		ИЛИ &Склад = ЗНАЧЕНИЕ(Справочник.Склады.ПустаяСсылка))

16