---

ВЫБРАТЬ
	ТаблицаИзменений.Номенклатура КАК Номенклатура,
	ТаблицаИзменений.Характеристика КАК Характеристика,
	ТаблицаИзменений.Назначение КАК Назначение,
	ТаблицаИзменений.Серия КАК Серия,
	ТаблицаИзменений.Упаковка КАК Упаковка,
	ТаблицаИзменений.Ячейка КАК Ячейка,
	СУММА(ТаблицаИзменений.ВНаличииИзменение) КАК ВНаличииИзменение,
	СУММА(ТаблицаИзменений.КОтборуИзменение) КАК КОтборуИзменение,
	СУММА(ТаблицаИзменений.КРазмещениюИзменение) КАК КРазмещениюИзменение
ПОМЕСТИТЬ ДвиженияТоварыВЯчейкахИзменение
ИЗ
	(ВЫБРАТЬ
		Таблица.Номенклатура КАК Номенклатура,
		Таблица.Характеристика КАК Характеристика,
		Таблица.Назначение КАК Назначение,
		Таблица.Серия КАК Серия,
		Таблица.Упаковка КАК Упаковка,
		Таблица.Ячейка КАК Ячейка,
		Таблица.ВНаличииПередЗаписью КАК ВНаличииИзменение,
		Таблица.КОтборуПередЗаписью КАК КОтборуИзменение,
		Таблица.КРазмещениюПередЗаписью КАК КРазмещениюИзменение
	ИЗ
		ДвиженияТоварыВЯчейкахПередЗаписью КАК Таблица
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		Таблица.Номенклатура,
		Таблица.Характеристика,
		Таблица.Назначение,
		Таблица.Серия,
		Таблица.Упаковка,
		Таблица.Ячейка,
		ВЫБОР
			КОГДА Таблица.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)
				ТОГДА -Таблица.ВНаличии
			ИНАЧЕ Таблица.ВНаличии
		КОНЕЦ,
		ВЫБОР
			КОГДА Таблица.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)
				ТОГДА -Таблица.КОтбору
			ИНАЧЕ Таблица.КОтбору
		КОНЕЦ,
		ВЫБОР
			КОГДА Таблица.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)
				ТОГДА -Таблица.КРазмещению
			ИНАЧЕ Таблица.КРазмещению
		КОНЕЦ
	ИЗ
		РегистрНакопления.ТоварыВЯчейках КАК Таблица
	ГДЕ
		Таблица.Регистратор = &Регистратор
		И Таблица.Ячейка.ТипСкладскойЯчейки В(&МассивТиповЯчеек)) КАК ТаблицаИзменений

СГРУППИРОВАТЬ ПО
	ТаблицаИзменений.Номенклатура,
	ТаблицаИзменений.Упаковка,
	ТаблицаИзменений.Характеристика,
	ТаблицаИзменений.Назначение,
	ТаблицаИзменений.Серия,
	ТаблицаИзменений.Ячейка

ИМЕЮЩИЕ
	(СУММА(ТаблицаИзменений.ВНаличииИзменение) > 0
		ИЛИ СУММА(ТаблицаИзменений.КОтборуИзменение) < 0
		ИЛИ СУММА(ТаблицаИзменений.КРазмещениюИзменение) < 0)
;

////////////////////////////////////////////////////////////////////////////////
УНИЧТОЖИТЬ ДвиженияТоварыВЯчейкахПередЗаписью;

ВЫБРАТЬ
	ТоварыВЯчейкахОстатки.Номенклатура КАК Номенклатура,
	ТоварыВЯчейкахОстатки.Характеристика КАК Характеристика,
	ТоварыВЯчейкахОстатки.Назначение КАК Назначение,
	ВЫБОР
		КОГДА ТоварыВЯчейкахОстатки.Упаковка = ЗНАЧЕНИЕ(Справочник.УпаковкиЕдиницыИзмерения.ПустаяСсылка)
			ТОГДА
				ТоварыВЯчейкахОстатки.Номенклатура.ЕдиницаИзмерения
			ИНАЧЕ
				ТоварыВЯчейкахОстатки.Упаковка
		КОНЕЦ КАК Упаковка,
	ТаблицаИзменений.Серия КАК Серия,
	ТоварыВЯчейкахОстатки.Ячейка КАК Ячейка,
	СУММА(ТоварыВЯчейкахОстатки.ВНаличииОстаток - ТоварыВЯчейкахОстатки.КОтборуОстаток) КАК Количество
ИЗ
	ДвиженияТоварыВЯчейкахИзменение КАК ТаблицаИзменений
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыВЯчейках.Остатки(
				,
				(Номенклатура, Характеристика, Назначение, Упаковка, Ячейка) В
					(ВЫБРАТЬ
						Таблица.Номенклатура,
						Таблица.Характеристика,
						Таблица.Назначение,
						Таблица.Упаковка,
						Таблица.Ячейка
					ИЗ
						ДвиженияТоварыВЯчейкахИзменение КАК Таблица)) КАК ТоварыВЯчейкахОстатки
		ПО ТаблицаИзменений.Номенклатура = ТоварыВЯчейкахОстатки.Номенклатура
			И ТаблицаИзменений.Характеристика = ТоварыВЯчейкахОстатки.Характеристика
			И ТаблицаИзменений.Назначение = ТоварыВЯчейкахОстатки.Назначение
			И ТаблицаИзменений.Упаковка = ТоварыВЯчейкахОстатки.Упаковка
			И ТаблицаИзменений.Ячейка = ТоварыВЯчейкахОстатки.Ячейка
			И (ВЫБОР
				КОГДА ТаблицаИзменений.Серия = ЗНАЧЕНИЕ(Справочник.СерииНоменклатуры.ПустаяСсылка)
					ТОГДА ИСТИНА
				ИНАЧЕ ТаблицаИзменений.Серия = ТоварыВЯчейкахОстатки.Серия
			КОНЕЦ)

СГРУППИРОВАТЬ ПО
	ТоварыВЯчейкахОстатки.Номенклатура,
	ТоварыВЯчейкахОстатки.Характеристика,
	ТоварыВЯчейкахОстатки.Назначение,
	ТоварыВЯчейкахОстатки.Упаковка,
	ТаблицаИзменений.Серия,
	ТоварыВЯчейкахОстатки.Ячейка

ИМЕЮЩИЕ
	СУММА(ТоварыВЯчейкахОстатки.ВНаличииОстаток - ТоварыВЯчейкахОстатки.КОтборуОстаток) < 0