---

ВЫБРАТЬ
	ОтмененныеРемонты.ID КАК ID,
	ОтмененныеРемонты.ОбъектРемонта КАК ОбъектРемонта,
	ВЫБОР
		КОГДА ОтмененныеРемонты.ПричинаЗакрытия = &ПричинаЗакрытияМонтажДемонтаж
			ТОГДА "Демонтаж ОР"
		ИНАЧЕ "Дефект устранен"
	КОНЕЦ КАК ПричинаЗакрытия
ПОМЕСТИТЬ ВТ_ПричиныЗакрытия
ИЗ
	РегистрСведений.торо_ОтмененныеРемонты.СрезПоследних(&ДатаОкончания, ) КАК ОтмененныеРемонты
ГДЕ
	ОтмененныеРемонты.Отменен

ИНДЕКСИРОВАТЬ ПО
	ID,
	ОбъектРемонта
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	тн_ГТМ.Период КАК ДатаСоздания,
	тн_ГТМ.Регистратор КАК Ссылка,
	тн_ГТМ.ОбъектРемонта КАК ОбъектРемонта,
	тн_ГТМ.ID КАК ID,
	тн_ГТМ.ДлинаХодаТекущее КАК ДлинаХодаТекущее,
	тн_ГТМ.ДлинаХодаПлан КАК ДлинаХодаПлан,
	тн_ГТМ.ЧислоКачанийТекущее КАК ЧислоКачанийТекущее,
	тн_ГТМ.ЧислоКачанийПлан КАК ЧислоКачанийПлан,
	тн_ГТМ.Прирост КАК Прирост,
	тн_ГТМ.СрокВыполнения КАК СрокВыполнения,
	тн_ГТМ.ЦельВыполненияГТМ КАК ЦельВыполненияГТМ,
	торо_ВнешнееОснованиеДляРаботОбследованноеОборудование.Ссылка.Номер КАК Номер,
	торо_ВнешнееОснованиеДляРаботОбследованноеОборудование.Ссылка.Проведен КАК Проведен,
	торо_ВнешнееОснованиеДляРаботОбследованноеОборудование.Ссылка.Комментарий КАК Комментарий,
	торо_ВнешнееОснованиеДляРаботОбследованноеОборудование.Ссылка.Организация КАК Организация,
	торо_ВнешнееОснованиеДляРаботОбследованноеОборудование.Ссылка.Подразделение КАК Подразделение,
	торо_ВнешнееОснованиеДляРаботОбследованноеОборудование.тн_ПроизводственныйОбъект КАК ПроизводственныйОбъект,
	торо_ВнешнееОснованиеДляРаботОбследованноеОборудование.Исполнитель КАК Исполнитель,
	торо_ВнешнееОснованиеДляРаботОбследованноеОборудование.тн_ПодразделениеИсполнителяПоРемонтам КАК ПодразделениеИсполнителяПоРемонтам,
	торо_ВнешнееОснованиеДляРаботОбследованноеОборудование.Ссылка.Ответственный КАК Ответственный,
	торо_ОбъектыРемонта.ТиповойОР КАК ТиповойОР,
	ПРЕДСТАВЛЕНИЕССЫЛКИ(торо_ВнешнееОснованиеДляРаботРемонтныеРаботы.РемонтнаяРабота) КАК РемонтнаяРабота,
	ВЫБОР
		КОГДА тн_ГТМ.ДлинаХодаПлан > тн_ГТМ.ДлинаХодаТекущее
			ТОГДА "Увеличение"
		КОГДА тн_ГТМ.ДлинаХодаПлан < тн_ГТМ.ДлинаХодаТекущее
			ТОГДА "Уменьшение"
		ИНАЧЕ ""
	КОНЕЦ КАК ДлинаХодаУвеличениеУменьшение,
	ВЫБОР
		КОГДА тн_ГТМ.ЧислоКачанийПлан > тн_ГТМ.ЧислоКачанийТекущее
			ТОГДА "Увеличение"
		КОГДА тн_ГТМ.ЧислоКачанийПлан < тн_ГТМ.ЧислоКачанийТекущее
			ТОГДА "Уменьшение"
		ИНАЧЕ ""
	КОНЕЦ КАК ЧислоКачанийУвеличениеУменьшение,
	ВЫБОР
		КОГДА тн_ГТМ.ДлинаХодаПлан <> тн_ГТМ.ДлинаХодаТекущее
			И тн_ГТМ.ЧислоКачанийПлан <> тн_ГТМ.ЧислоКачанийТекущее
			ТОГДА "Механика/Энергетика"
		КОГДА тн_ГТМ.ДлинаХодаПлан <> тн_ГТМ.ДлинаХодаТекущее
			ТОГДА "Механика"
		КОГДА тн_ГТМ.ЧислоКачанийПлан <> тн_ГТМ.ЧислоКачанийТекущее
			ТОГДА "Энергетика"
		ИНАЧЕ ""
	КОНЕЦ КАК ЗонаОтветственностиГТМ,
	торо_ВнешнееОснованиеДляРаботОбследованноеОборудование.Описание КАК Описание,
	торо_ВнешнееОснованиеДляРаботРемонтныеРаботы.Ссылка.тн_КодАРМИТС КАК тн_КодАРМИТС,
	ВЫБОР
		КОГДА ПричиныЗакрытия.ID ЕСТЬ NULL
			ТОГДА ""
		ИНАЧЕ ПричиныЗакрытия.ПричинаЗакрытия
	КОНЕЦ КАК ПричинаЗакрытия
ПОМЕСТИТЬ ВТ_Данные
ИЗ
	РегистрСведений.тн_ГТМ КАК тн_ГТМ
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.торо_ВнешнееОснованиеДляРабот.ОбследованноеОборудование КАК торо_ВнешнееОснованиеДляРаботОбследованноеОборудование
		ПО тн_ГТМ.Регистратор = торо_ВнешнееОснованиеДляРаботОбследованноеОборудование.Ссылка
			И тн_ГТМ.ОбъектРемонта = торо_ВнешнееОснованиеДляРаботОбследованноеОборудование.ОбъектРемонта
			И тн_ГТМ.ID = торо_ВнешнееОснованиеДляРаботОбследованноеОборудование.ID
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.торо_ОбъектыРемонта КАК торо_ОбъектыРемонта
		ПО тн_ГТМ.ОбъектРемонта = торо_ОбъектыРемонта.Ссылка
		ЛЕВОЕ СОЕДИНЕНИЕ Документ.торо_ВнешнееОснованиеДляРабот.РемонтныеРаботы КАК торо_ВнешнееОснованиеДляРаботРемонтныеРаботы
		ПО тн_ГТМ.Регистратор = торо_ВнешнееОснованиеДляРаботРемонтныеРаботы.Ссылка
			И тн_ГТМ.ID = торо_ВнешнееОснованиеДляРаботРемонтныеРаботы.Предписание_ID
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_ПричиныЗакрытия КАК ПричиныЗакрытия
		ПО тн_ГТМ.ID = ПричиныЗакрытия.ID
			И тн_ГТМ.ОбъектРемонта = ПричиныЗакрытия.ОбъектРемонта
ГДЕ
	тн_ГТМ.Период МЕЖДУ &ДатаНачала И &ДатаОкончания
	И торо_ОбъектыРемонта.Направление В (&Направление)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
	ВТ_Данные.ОбъектРемонта КАК ОбъектРемонта,
	ВТ_Данные.ТиповойОР КАК ТиповойОР
ПОМЕСТИТЬ ВТ_ДанныеОР
ИЗ
	ВТ_Данные КАК ВТ_Данные
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	торо_СтатусыДокументовСрезПоследних.ИзменяемыйДокумент КАК ИзменяемыйДокумент,
	торо_СтатусыДокументовСрезПоследних.Статус КАК Статус
ПОМЕСТИТЬ ВТ_СтатусыДокументов
ИЗ
	РегистрСведений.торо_СтатусыДокументов.СрезПоследних(&ДатаОкончания, ИзменяемыйДокумент В
		(ВЫБРАТЬ
			ВТ_Данные.Ссылка
		ИЗ
			ВТ_Данные КАК ВТ_Данные)) КАК торо_СтатусыДокументовСрезПоследних
ГДЕ
	торо_СтатусыДокументовСрезПоследних.Статус В (&СтатусДокумента)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_ДанныеОР.ОбъектРемонта КАК Ссылка,
	МАКСИМУМ(торо_ОбъектыРемонтаДополнительныеРеквизиты.Значение) КАК Значение
ПОМЕСТИТЬ ВТ_НоминальнаяЧастота
ИЗ
	Справочник.торо_ОбъектыРемонта.ДополнительныеРеквизиты КАК торо_ОбъектыРемонтаДополнительныеРеквизиты
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_ДанныеОР КАК ВТ_ДанныеОР
		ПО торо_ОбъектыРемонтаДополнительныеРеквизиты.Ссылка = ВТ_ДанныеОР.ОбъектРемонта
ГДЕ
	торо_ОбъектыРемонтаДополнительныеРеквизиты.Свойство = &Свойство
СГРУППИРОВАТЬ ПО
	ВТ_ДанныеОР.ОбъектРемонта

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ВТ_ДанныеОР.ОбъектРемонта,
	МАКСИМУМ(торо_ТиповыеОРДополнительныеРеквизиты.Значение)
ИЗ
	Справочник.торо_ТиповыеОР.ДополнительныеРеквизиты КАК торо_ТиповыеОРДополнительныеРеквизиты
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_ДанныеОР КАК ВТ_ДанныеОР
		ПО торо_ТиповыеОРДополнительныеРеквизиты.Ссылка = ВТ_ДанныеОР.ТиповойОР
ГДЕ
	торо_ТиповыеОРДополнительныеРеквизиты.Свойство = &Свойство
СГРУППИРОВАТЬ ПО
	ВТ_ДанныеОР.ОбъектРемонта
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_НоминальнаяЧастота.Ссылка КАК Ссылка,
	МАКСИМУМ(ВТ_НоминальнаяЧастота.Значение) КАК Значение
ПОМЕСТИТЬ ВТ_НоминальнаяЧастотаГруппировка
ИЗ
	ВТ_НоминальнаяЧастота КАК ВТ_НоминальнаяЧастота
СГРУППИРОВАТЬ ПО
	ВТ_НоминальнаяЧастота.Ссылка
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_ДанныеОР.ОбъектРемонта КАК ОбъектРемонта,
	торо_ИзмеряемыеПоказателиОбъектовРемонта.Показатель КАК Показатель
ПОМЕСТИТЬ вт_Показатели
ИЗ
	ВТ_ДанныеОР КАК ВТ_ДанныеОР
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.торо_ИзмеряемыеПоказателиОбъектовРемонта КАК торо_ИзмеряемыеПоказателиОбъектовРемонта
		ПО ВТ_ДанныеОР.ТиповойОР = торо_ИзмеряемыеПоказателиОбъектовРемонта.ОбъектРемонта
ГДЕ
	торо_ИзмеряемыеПоказателиОбъектовРемонта.Показатель = &ДиаметрШкива

ИНДЕКСИРОВАТЬ ПО
	ОбъектРемонта,
	Показатель
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	вт_Показатели.ОбъектРемонта КАК ОбъектРемонта,
	торо_ЗначенияКонтролируемыхПоказателейСрезПоследних.Показатель КАК Показатель,
	МАКСИМУМ(торо_ЗначенияКонтролируемыхПоказателейСрезПоследних.ДатаКонтроля) КАК ДатаКонтроля
ПОМЕСТИТЬ вт_ПериодыПоказаний
ИЗ
	вт_Показатели КАК вт_Показатели
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.торо_ЗначенияКонтролируемыхПоказателей.СрезПоследних(&ДатаОкончания,
			(ОбъектРемонта, Показатель) В
			(ВЫБРАТЬ
				вт_Показатели.ОбъектРемонта,
				вт_Показатели.Показатель
			ИЗ
				вт_Показатели)) КАК торо_ЗначенияКонтролируемыхПоказателейСрезПоследних
		ПО вт_Показатели.ОбъектРемонта = торо_ЗначенияКонтролируемыхПоказателейСрезПоследних.ОбъектРемонта
			И вт_Показатели.Показатель = торо_ЗначенияКонтролируемыхПоказателейСрезПоследних.Показатель
СГРУППИРОВАТЬ ПО
	торо_ЗначенияКонтролируемыхПоказателейСрезПоследних.Показатель,
	вт_Показатели.ОбъектРемонта

ИНДЕКСИРОВАТЬ ПО
	Показатель,
	ОбъектРемонта,
	ДатаКонтроля
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	вт_ПериодыПоказаний.ОбъектРемонта КАК ОбъектРемонта,
	торо_ЗначенияКонтролируемыхПоказателейСрезПоследних.Значение КАК Значение
ПОМЕСТИТЬ вт_ЗначенияПоказателей
ИЗ
	вт_ПериодыПоказаний КАК вт_ПериодыПоказаний
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.торо_ЗначенияКонтролируемыхПоказателей.СрезПоследних(&ДатаОкончания,
			(ОбъектРемонта, Показатель) В
			(ВЫБРАТЬ
				вт_ПериодыПоказаний.ОбъектРемонта,
				вт_ПериодыПоказаний.Показатель
			ИЗ
				вт_ПериодыПоказаний)) КАК торо_ЗначенияКонтролируемыхПоказателейСрезПоследних
		ПО вт_ПериодыПоказаний.Показатель = торо_ЗначенияКонтролируемыхПоказателейСрезПоследних.Показатель
			И вт_ПериодыПоказаний.ОбъектРемонта = торо_ЗначенияКонтролируемыхПоказателейСрезПоследних.ОбъектРемонта
			И вт_ПериодыПоказаний.ДатаКонтроля = торо_ЗначенияКонтролируемыхПоказателейСрезПоследних.ДатаКонтроля

ИНДЕКСИРОВАТЬ ПО
	ОбъектРемонта
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	торо_РасположениеОРВСтруктуреИерархииСрезПоследних.ОбъектИерархии КАК ОбъектИерархии,
	торо_РасположениеОРВСтруктуреИерархииСрезПоследних.РодительИерархии КАК РодительИерархии
ПОМЕСТИТЬ ТаблицаИерархии
ИЗ
	РегистрСведений.торо_РасположениеОРВСтруктуреИерархии.СрезПоследних(&ДатаОкончания, СтруктураИерархии = &СтруктураИерархии И ОбъектИерархии.Направление В (&Направление)) КАК торо_РасположениеОРВСтруктуреИерархииСрезПоследних
ГДЕ
	торо_РасположениеОРВСтруктуреИерархииСрезПоследних.Удален = ЛОЖЬ

ИНДЕКСИРОВАТЬ ПО
	РодительИерархии
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ТаблицаИерархии.РодительИерархии КАК РодительИерархии,
	ТаблицаИерархии.ОбъектИерархии КАК ОбъектРемонта
ПОМЕСТИТЬ ВТ_ФМ
ИЗ
	ТаблицаИерархии КАК ТаблицаИерархии
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_ДанныеОР КАК ВТ_ДанныеОР
		ПО ТаблицаИерархии.ОбъектИерархии = ВТ_ДанныеОР.ОбъектРемонта
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ТаблицаИерархии.РодительИерархии КАК РодительИерархии,
	ТаблицаИерархии.ОбъектИерархии КАК ОбъектИерархии
ПОМЕСТИТЬ ВТ_ФМСПодчиненными
ИЗ
	ТаблицаИерархии КАК ТаблицаИерархии
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_ФМ КАК ВТ_ФМ
		ПО ТаблицаИерархии.РодительИерархии = ВТ_ФМ.РодительИерархии
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_ФМСПодчиненными.РодительИерархии КАК РодительИерархии,
	ВТ_ФМСПодчиненными.ОбъектИерархии КАК ОбъектИерархии
ПОМЕСТИТЬ ВТ_Приводы
ИЗ
	ВТ_ФМСПодчиненными КАК ВТ_ФМСПодчиненными
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.торо_ОбъектыРемонта КАК торо_ОбъектыРемонта
		ПО ВТ_ФМСПодчиненными.ОбъектИерархии = торо_ОбъектыРемонта.Ссылка
ГДЕ
	торо_ОбъектыРемонта.Направление В (&Приводы)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_ФМСПодчиненными.РодительИерархии КАК РодительИерархии,
	ВТ_ФМСПодчиненными.ОбъектИерархии КАК ОбъектИерархии
ПОМЕСТИТЬ ВТ_СтанцииУправления
ИЗ
	ВТ_ФМСПодчиненными КАК ВТ_ФМСПодчиненными
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.торо_ОбъектыРемонта КАК торо_ОбъектыРемонта
		ПО ВТ_ФМСПодчиненными.ОбъектИерархии = торо_ОбъектыРемонта.Ссылка
ГДЕ
	торо_ОбъектыРемонта.Направление = &СтанцияУправления
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_ФМ.ОбъектРемонта КАК ОбъектРемонта,
	ВТ_СтанцииУправления.ОбъектИерархии КАК СтанцияУправления
ПОМЕСТИТЬ ВТ_СтанцииУправленияОР
ИЗ
	ВТ_ФМ КАК ВТ_ФМ
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_СтанцииУправления КАК ВТ_СтанцииУправления
		ПО ВТ_ФМ.РодительИерархии = ВТ_СтанцииУправления.РодительИерархии
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_ФМ.РодительИерархии КАК РодительИерархии,
	ВТ_ФМ.ОбъектРемонта КАК ОбъектРемонта,
	КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ВТ_Приводы.ОбъектИерархии) КАК Количество
ПОМЕСТИТЬ ВТ_КоличествоПриводов
ИЗ
	ВТ_ФМ КАК ВТ_ФМ
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_Приводы КАК ВТ_Приводы
		ПО ВТ_ФМ.РодительИерархии = ВТ_Приводы.РодительИерархии
СГРУППИРОВАТЬ ПО
	ВТ_ФМ.РодительИерархии,
	ВТ_ФМ.ОбъектРемонта
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_КоличествоПриводов.ОбъектРемонта КАК ОбъектРемонта,
	ВТ_Приводы.ОбъектИерархии КАК Привод
ПОМЕСТИТЬ ВТ_ОдинПривод
ИЗ
	ВТ_КоличествоПриводов КАК ВТ_КоличествоПриводов
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_Приводы КАК ВТ_Приводы
		ПО ВТ_КоличествоПриводов.РодительИерархии = ВТ_Приводы.РодительИерархии
ГДЕ
	ВТ_КоличествоПриводов.Количество = 1
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_КоличествоПриводов.ОбъектРемонта КАК ОбъектРемонта,
	ВТ_Приводы.ОбъектИерархии КАК Привод
ПОМЕСТИТЬ ВТ_НесколькоПриводов
ИЗ
	ВТ_КоличествоПриводов КАК ВТ_КоличествоПриводов
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_Приводы КАК ВТ_Приводы
		ПО ВТ_КоличествоПриводов.РодительИерархии = ВТ_Приводы.РодительИерархии
ГДЕ
	ВТ_КоличествоПриводов.Количество >= 1
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_Данные.ДатаСоздания КАК ДатаСоздания,
	ВТ_Данные.Ссылка КАК Ссылка,
	ВТ_Данные.ОбъектРемонта КАК ОбъектРемонта,
	ВТ_Данные.ID КАК ID,
	ВТ_Данные.ДлинаХодаТекущее КАК ДлинаХодаТекущее,
	ВТ_Данные.ДлинаХодаПлан КАК ДлинаХодаПлан,
	ВТ_Данные.ЧислоКачанийТекущее КАК ЧислоКачанийТекущее,
	ВТ_Данные.ЧислоКачанийПлан КАК ЧислоКачанийПлан,
	ВТ_Данные.Прирост КАК Прирост,
	ВТ_Данные.СрокВыполнения КАК СрокВыполнения,
	ВТ_Данные.ЦельВыполненияГТМ КАК ЦельВыполненияГТМ,
	ВТ_Данные.Номер КАК Номер,
	ВТ_Данные.Проведен КАК Проведен,
	ВТ_Данные.Комментарий КАК Комментарий,
	ВТ_Данные.Организация КАК Организация,
	ВТ_Данные.Подразделение КАК Подразделение,
	ВТ_Данные.ПроизводственныйОбъект КАК ПроизводственныйОбъект,
	ВТ_Данные.Исполнитель КАК Исполнитель,
	ВТ_Данные.ПодразделениеИсполнителяПоРемонтам КАК ПодразделениеИсполнителяПоРемонтам,
	ВТ_Данные.Ответственный КАК Ответственный,
	ВТ_Данные.ТиповойОР КАК ТиповойОР,
	ВТ_Данные.РемонтнаяРабота КАК РемонтнаяРабота,
	ВТ_Данные.ДлинаХодаУвеличениеУменьшение КАК ДлинаХодаУвеличениеУменьшение,
	ВТ_Данные.ЧислоКачанийУвеличениеУменьшение КАК ЧислоКачанийУвеличениеУменьшение,
	ВТ_Данные.ЗонаОтветственностиГТМ КАК ЗонаОтветственностиГТМ,
	ВТ_СтатусыДокументов.Статус КАК СтатусДокумента,
	ВТ_НоминальнаяЧастотаГруппировка.Значение КАК ТекущаяЧастотаВращенияЭлектродвигателя,
	вт_ЗначенияПоказателей.Значение КАК ДиаметрШкива,
	ВТ_СтанцииУправленияОР.СтанцияУправления КАК СтанцияУправления,
	ВТ_ОдинПривод.Привод КАК Привод,
	ВТ_Данные.Описание КАК Описание,
	ВТ_Данные.тн_КодАРМИТС КАК тн_КодАРМИТС,
	ВТ_Данные.ПричинаЗакрытия КАК ПричинаЗакрытия
ПОМЕСТИТЬ ВТ_Итог
ИЗ
	ВТ_Данные КАК ВТ_Данные
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_СтатусыДокументов КАК ВТ_СтатусыДокументов
		ПО ВТ_Данные.Ссылка = ВТ_СтатусыДокументов.ИзменяемыйДокумент
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_НоминальнаяЧастотаГруппировка КАК ВТ_НоминальнаяЧастотаГруппировка
		ПО ВТ_Данные.ОбъектРемонта = ВТ_НоминальнаяЧастотаГруппировка.Ссылка
		ЛЕВОЕ СОЕДИНЕНИЕ вт_ЗначенияПоказателей КАК вт_ЗначенияПоказателей
		ПО ВТ_Данные.ОбъектРемонта = вт_ЗначенияПоказателей.ОбъектРемонта
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_СтанцииУправленияОР КАК ВТ_СтанцииУправленияОР
		ПО ВТ_Данные.ОбъектРемонта = ВТ_СтанцииУправленияОР.ОбъектРемонта
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_ОдинПривод КАК ВТ_ОдинПривод
		ПО ВТ_Данные.ОбъектРемонта = ВТ_ОдинПривод.ОбъектРемонта
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_Итог.Привод КАК Привод,
	тн_ГТМ.Регистратор КАК Ссылка
ПОМЕСТИТЬ ВТ_ПрошлыеГТМ
ИЗ
	РегистрСведений.тн_ГТМ КАК тн_ГТМ
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_Итог КАК ВТ_Итог
		ПО тн_ГТМ.ОбъектРемонта = ВТ_Итог.Привод
			И тн_ГТМ.Регистратор <> ВТ_Итог.Ссылка
			И тн_ГТМ.Период <= ВТ_Итог.ДатаСоздания
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	торо_СтатусыДокументовСрезПоследних.ИзменяемыйДокумент КАК Ссылка
ПОМЕСТИТЬ ВТ_ВыполненныеГТМ
ИЗ
	РегистрСведений.торо_СтатусыДокументов.СрезПоследних(&ДатаОкончания, ИзменяемыйДокумент В
		(ВЫБРАТЬ
			ВТ_ПрошлыеГТМ.Ссылка
		ИЗ
			ВТ_ПрошлыеГТМ КАК ВТ_ПрошлыеГТМ)) КАК торо_СтатусыДокументовСрезПоследних
ГДЕ
	торо_СтатусыДокументовСрезПоследних.Статус = ЗНАЧЕНИЕ(Перечисление.торо_СтатусыДокументов.Выполнен)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_ПрошлыеГТМ.Привод КАК Привод,
	МАКСИМУМ(тн_ГТМ.Период) КАК Период
ПОМЕСТИТЬ ВТ_ДатыПрошлыхГТМ
ИЗ
	ВТ_ПрошлыеГТМ КАК ВТ_ПрошлыеГТМ
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_ВыполненныеГТМ КАК ВТ_ВыполненныеГТМ
		ПО ВТ_ПрошлыеГТМ.Ссылка = ВТ_ВыполненныеГТМ.Ссылка
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.тн_ГТМ КАК тн_ГТМ
		ПО ВТ_ПрошлыеГТМ.Ссылка = тн_ГТМ.Регистратор
			И ВТ_ПрошлыеГТМ.Привод = тн_ГТМ.ОбъектРемонта
СГРУППИРОВАТЬ ПО
	ВТ_ПрошлыеГТМ.Привод
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	тн_ИсторияПоложенияОРСрезПоследних.ОбъектРемонта КАК Привод,
	МАКСИМУМ(тн_ИсторияПоложенияОРСрезПоследних.Период) КАК Период
ПОМЕСТИТЬ ВТ_ДатыМонтажаПривода
ИЗ
	РегистрСведений.тн_ИсторияПоложенияОР.СрезПоследних(&ТекущаяДата, ОбъектРемонта В
		(ВЫБРАТЬ
			ВТ_НесколькоПриводов.Привод
		ИЗ
			ВТ_НесколькоПриводов КАК ВТ_НесколькоПриводов)) КАК тн_ИсторияПоложенияОРСрезПоследних
СГРУППИРОВАТЬ ПО
	тн_ИсторияПоложенияОРСрезПоследних.ОбъектРемонта
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_НесколькоПриводов.ОбъектРемонта КАК ОбъектРемонта,
	ВТ_НесколькоПриводов.Привод КАК Привод,
	ВТ_ДатыМонтажаПривода.Период КАК Период
ПОМЕСТИТЬ ВТ_ДатыМонтажаПриводаСОР
ИЗ
	ВТ_НесколькоПриводов КАК ВТ_НесколькоПриводов
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_ДатыМонтажаПривода КАК ВТ_ДатыМонтажаПривода
		ПО ВТ_НесколькоПриводов.Привод = ВТ_ДатыМонтажаПривода.Привод
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_Итог.ДатаСоздания КАК ДатаСоздания,
	ВТ_Итог.Ссылка КАК Ссылка,
	ВТ_Итог.ОбъектРемонта КАК ОбъектРемонта,
	ВТ_Итог.ID КАК ID,
	ВТ_Итог.ДлинаХодаТекущее КАК ДлинаХодаТекущее,
	ВТ_Итог.ДлинаХодаПлан КАК ДлинаХодаПлан,
	ВТ_Итог.ЧислоКачанийТекущее КАК ЧислоКачанийТекущее,
	ВТ_Итог.ЧислоКачанийПлан КАК ЧислоКачанийПлан,
	ВТ_Итог.Прирост КАК Прирост,
	ВТ_Итог.СрокВыполнения КАК СрокВыполнения,
	ВТ_Итог.ЦельВыполненияГТМ КАК ЦельВыполненияГТМ,
	ВТ_Итог.Номер КАК Номер,
	ВТ_Итог.Проведен КАК Проведен,
	ВТ_Итог.Комментарий КАК Комментарий,
	ВТ_Итог.Организация КАК Организация,
	ВТ_Итог.Подразделение КАК Подразделение,
	ВТ_Итог.ПроизводственныйОбъект КАК ПроизводственныйОбъект,
	ВТ_Итог.Исполнитель КАК Исполнитель,
	ВТ_Итог.ПодразделениеИсполнителяПоРемонтам КАК ПодразделениеИсполнителяПоРемонтам,
	ВТ_Итог.Ответственный КАК Ответственный,
	ВТ_Итог.ТиповойОР КАК ТиповойОР,
	ВТ_Итог.РемонтнаяРабота КАК РемонтнаяРабота,
	ВТ_Итог.ДлинаХодаУвеличениеУменьшение КАК ДлинаХодаУвеличениеУменьшение,
	ВТ_Итог.ЧислоКачанийУвеличениеУменьшение КАК ЧислоКачанийУвеличениеУменьшение,
	ВТ_Итог.ЗонаОтветственностиГТМ КАК ЗонаОтветственностиГТМ,
	ВТ_Итог.СтатусДокумента КАК СтатусДокумента,
	ВТ_Итог.ТекущаяЧастотаВращенияЭлектродвигателя КАК ТекущаяЧастотаВращенияЭлектродвигателя,
	ВТ_Итог.ДиаметрШкива КАК ДиаметрШкива,
	ВТ_Итог.СтанцияУправления КАК СтанцияУправления,
	ВТ_ДатыПрошлыхГТМ.Период КАК ДатаПредыдущегоВыполненногоГТМ,
	ЕСТЬNULL(ВТ_ДатыМонтажаПриводаСОР.Период, "Нет привода") КАК ДатаМонтажаПривода,
	ВТ_Итог.Описание КАК Описание,
	ВТ_Итог.тн_КодАРМИТС КАК тн_КодАРМИТС,
	"" КАК СводнаяИнформацияНаГТМ,
	ВТ_Итог.ПричинаЗакрытия КАК ПричинаЗакрытия
ИЗ
	ВТ_Итог КАК ВТ_Итог
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_ДатыПрошлыхГТМ КАК ВТ_ДатыПрошлыхГТМ
		ПО ВТ_Итог.Привод = ВТ_ДатыПрошлыхГТМ.Привод
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_ДатыМонтажаПриводаСОР КАК ВТ_ДатыМонтажаПриводаСОР
		ПО ВТ_Итог.ОбъектРемонта = ВТ_ДатыМонтажаПриводаСОР.ОбъектРемонта