---

@echo off
setlocal DisableDelayedExpansion

set "NETPING1_IP=192.168.88.38"
set "NETPING1_USER=visor"
set "NETPING1_PASSWORD=Lambo002"

set "NETPING2_IP=192.168.88.39"
set "NETPING2_USER=visor"
set "NETPING2_PASSWORD=Lambo002"

set "NETPING_IP="
set "NETPING_USER="
set "NETPING_PASSWORD="
set "RELAY="

rem Console 44 -> NetPing 1, outlet 1
if "%~1"=="44" (
    set "NETPING_IP=%NETPING1_IP%"
    set "NETPING_USER=%NETPING1_USER%"
    set "NETPING_PASSWORD=%NETPING1_PASSWORD%"
    set "RELAY=1"
)

rem Console 45 -> NetPing 1, outlet 2
if "%~1"=="45" (
    set "NETPING_IP=%NETPING1_IP%"
    set "NETPING_USER=%NETPING1_USER%"
    set "NETPING_PASSWORD=%NETPING1_PASSWORD%"
    set "RELAY=2"
)

rem Console 46 -> NetPing 2, outlet 1
if "%~1"=="46" (
    set "NETPING_IP=%NETPING2_IP%"
    set "NETPING_USER=%NETPING2_USER%"
    set "NETPING_PASSWORD=%NETPING2_PASSWORD%"
    set "RELAY=1"
)

rem Console 47 -> NetPing 2, outlet 2
if "%~1"=="47" (
    set "NETPING_IP=%NETPING2_IP%"
    set "NETPING_USER=%NETPING2_USER%"
    set "NETPING_PASSWORD=%NETPING2_PASSWORD%"
    set "RELAY=2"
)

if not defined NETPING_IP exit /b 2
if not defined RELAY exit /b 3

set "RESPONSE_FILE=%TEMP%\netping_on_%RANDOM%_%RANDOM%.tmp"

curl.exe --silent --show-error --fail --anyauth ^
  --connect-timeout 5 --max-time 10 ^
  --user "%NETPING_USER%:%NETPING_PASSWORD%" ^
  "http://%NETPING_IP%/relay.cgi?r%RELAY%=1" ^
  > "%RESPONSE_FILE%"

if errorlevel 1 (
    del "%RESPONSE_FILE%" 2>nul
    exit /b 10
)

findstr /i /c:"error" "%RESPONSE_FILE%" >nul
if not errorlevel 1 (
    del "%RESPONSE_FILE%" 2>nul
    exit /b 11
)

findstr /i /l /c:"relay_result('ok')" "%RESPONSE_FILE%" >nul
if errorlevel 1 (
    del "%RESPONSE_FILE%" 2>nul
    exit /b 12
)

del "%RESPONSE_FILE%" 2>nul
exit /b 0