---

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	УстановитьУсловноеОформление();
	
	ЗаполнитьСписокЗначенийПроизводственныйКалендарьНаСервере(); 
	Если ЗначениеЗаполнено(Объект.Год) Тогда
		НомерТекущегоГода = Объект.Год;
	КонецЕсли;
	
	
	ЗаполнитьДаннымиТекущегоГода();
	
	СформироватьШаблонРасписания();
		
	УстановитьДоступностьУчитыватьНерабочиеПериоды(); 
	
	УстановитьДоступностьУчитыватьПраздники(); 
	
	ЗаполнитьЦветаВидовДней();
	
	ЗаполнитьСписокВидовДня();
	
КонецПроцедуры   

&НаСервере
Процедура ЗаполнитьДаннымиПоУмолчанию()
	
	КодБазовогоКалендаря = Объект.ПроизводственныйКалендарь;
	Объект.Код = КодБазовогоКалендаря;
	
	ДанныеПоУмолчанию = Справочники.ГрафикРаботы.РезультатЗаполненияПроизводственногоКалендаряПоУмолчанию(
		Объект.Код, НомерТекущегоГода, КодБазовогоКалендаря
	); 
	
	Справочники.ГрафикРаботы.ОбновитьПериодыНерабочихДней(
		Справочники.ГрафикРаботы.ПериодыНерабочихДнейПоУмолчанию(), Объект.Код
	);
	
	ПреобразоватьДанныеПроизводственногоКалендаря(ДанныеПоУмолчанию);
	Модифицированность = Истина;
	
КонецПроцедуры



&НаСервере
Процедура ЗаполнитьДаннымиТекущегоГода()
	
	НастроитьПолеКалендаря();
	
	СсылкаНаКалендарь = Объект.Ссылка;
	
	ПрочитатьДанныеПроизводственногоКалендаря(СсылкаНаКалендарь, НомерТекущегоГода);
	ПрочитатьНерабочиеДаты(); 
	
	ДниГрафика = Новый ФиксированноеСоответствие(
	РегистрыСведений.КалендарныеГрафики.ПрочитатьДанныеГрафикаИзРегистра(Объект.Ссылка, НомерТекущегоГода));
	
	//ПрочитатьПризнакРучногоРедактирования(Объект, НомерТекущегоГода);
	
	// Если нет ручных корректировок и данных тоже нет, то формируем результат по шаблону за выбранный год.
	Если ДниГрафика.Количество() = 0 Тогда //И ДниИзмененные.Количество() = 0
		ПараметрыЗаполнения = РегистрыСведений.КалендарныеГрафики.ПараметрыЗаполненияГрафика();
		ПараметрыЗаполнения.КодПроизводственногоКалендаря = Объект.Код;
		//ПараметрыЗаполнения.СпособЗаполнения = Объект.СпособЗаполнения;
		ПараметрыЗаполнения.ШаблонЗаполнения = Объект.РабочиеДни;
		ПараметрыЗаполнения.ПроизводственныйКалендарь = Объект.Ссылка;
		ПараметрыЗаполнения.УчитыватьПраздники = Объект.УчитыватьПраздничныеДни;
		ПараметрыЗаполнения.УчитыватьНерабочиеПериоды = Объект.УчитыватьНерабочиеПериоды;
		//ПараметрыЗаполнения.ДатаОтсчета = Объект.ДатаОтсчета;
		ДниВключенныеВГрафик = РегистрыСведений.КалендарныеГрафики.ДниВключенныеВГрафик(
			Объект.ДатаНачала, Дата(НомерТекущегоГода, 12, 31), ПараметрыЗаполнения
		);
		ДниГрафика = Новый ФиксированноеСоответствие(ДниВключенныеВГрафик);
	КонецЕсли; 
	
КонецПроцедуры  

&НаСервере
Процедура ПрочитатьДанныеПроизводственногоКалендаря(ПроизводственныйКалендарь, НомерГода)
	
	// Загрузка данных производственного календаря за указанный год.
	ПреобразоватьДанныеПроизводственногоКалендаря(
		Справочники.ГрафикРаботы.ДанныеПроизводственногоКалендаря(ПроизводственныйКалендарь, НомерГода)
	);
КонецПроцедуры 

&НаСервере
Процедура ПреобразоватьДанныеПроизводственногоКалендаря(ДанныеПроизводственногоКалендаря)
	// Данные производственного календаря используются в форме 
	// в виде соответствий ВидыДней и ПереносыДней.
	// Процедура заполняет эти соответствия.
	
	ВидыДнейСоответствие = Новый Соответствие;
	ПереносыДнейСоответствие = Новый Соответствие;
	
	Для Каждого СтрокаТаблицы Из ДанныеПроизводственногоКалендаря Цикл
		ВидыДнейСоответствие.Вставить(СтрокаТаблицы.Дата, СтрокаТаблицы.ВидДня);
		Если ЗначениеЗаполнено(СтрокаТаблицы.ДатаПереноса) Тогда
			ПереносыДнейСоответствие.Вставить(СтрокаТаблицы.Дата, СтрокаТаблицы.ДатаПереноса);
		КонецЕсли;
	КонецЦикла;
	
	ВидыДней = Новый ФиксированноеСоответствие(ВидыДнейСоответствие);
	ПереносыДней = Новый ФиксированноеСоответствие(ПереносыДнейСоответствие);  
	/// ???
	//ЗаполнитьПредставлениеПереносов(ЭтотОбъект);
	
КонецПроцедуры

&НаСервере
Процедура УстановитьДоступностьУчитыватьНерабочиеПериоды()
	
	Элементы.УчитыватьНерабочиеПериоды.Видимость = Ложь;
	Если Не ЗначениеЗаполнено(Объект.ПроизводственныйКалендарь) Тогда
		Возврат;
	КонецЕсли;
	
	Периоды = РегистрыСведений.КалендарныеГрафики.ПериодыНерабочихДней(Объект.ПроизводственныйКалендарь, Новый СтандартныйПериод(Объект.ДатаНачала, Объект.ДатаОкончания), Объект.Код);
	Если Периоды.Количество() = 0 Тогда
		Возврат;
	КонецЕсли;
	
	Элементы.УчитыватьНерабочиеПериодыГруппа.Видимость = Истина;
	
	Пояснение = "";
	Для Каждого ОписаниеПериода Из Периоды Цикл
		Пояснение = Пояснение + ?(Не ПустаяСтрока(Пояснение), Символы.ПС, "") + ОписаниеПериода.Представление;
	КонецЦикла;
	Элементы.НерабочиеПериодыИнформация.Заголовок = Пояснение;
	
КонецПроцедуры  

&НаКлиентеНаСервереБезКонтекста
Процедура ЗаполнитьПредставлениеПереносов(Форма)
	
	// Формирует представление переносов в виде списка значений.
	
	Форма.СписокПереносов.Очистить();
	Для Каждого КлючИЗначение Из Форма.ПереносыДней Цикл
		// С прикладной точки зрения переносится всегда выходной день на рабочий, 
		// поэтому из двух дат выбираем ту, которой соответствовал выходной день (сейчас соответствует рабочий).
		ДатаИсточник = КлючИЗначение.Ключ;
		ДатаПриемник = КлючИЗначение.Значение;
		ВидДня = Форма.ВидыДней.Получить(ДатаИсточник);
		Если ВидДня = ПредопределенноеЗначение("Перечисление.ВидыДнейПроизводственногоКалендаря.Суббота")
			Или ВидДня = ПредопределенноеЗначение("Перечисление.ВидыДнейПроизводственногоКалендаря.Воскресенье") Тогда
			// Обменяем даты местами, чтобы отобразить сведения о переносе как "А на Б", а не "Б на А".
			ДатаПереноса = ДатаПриемник;
			ДатаПриемник = ДатаИсточник;
			ДатаИсточник = ДатаПереноса;
		КонецЕсли;
		Если Форма.СписокПереносов.НайтиПоЗначению(ДатаИсточник) <> Неопределено 
			Или Форма.СписокПереносов.НайтиПоЗначению(ДатаПриемник) <> Неопределено Тогда
			// Перенос уже добавлен, пропускаем.
			Продолжить;
		КонецЕсли;
		Форма.СписокПереносов.Добавить(ДатаИсточник, ПредставлениеПереноса(ДатаИсточник, ДатаПриемник));
	КонецЦикла;
	Форма.СписокПереносов.СортироватьПоЗначению();
	
	УстановитьВидимостьСпискаПереносов(Форма);
	
КонецПроцедуры 

&НаКлиентеНаСервереБезКонтекста
Функция ПредставлениеПереноса(ДатаИсточник, ДатаПриемник)
	
	Возврат СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
	НСтр("ru = 'с %1 %2 на %3 %4'"),
	ДеньНеделиВФормулировкеСКакогоПереносим(ДатаИсточник),
	Формат(ДатаИсточник, "ДФ='д ММММ'"), // АПК:1367 Хорошего решения нет, считаем сохранение порядка дата + месяц приемлемым решением в этом месте
	ДеньНеделиВФормулировкеНаКакойПереносим(ДатаПриемник),
	Формат(ДатаПриемник, "ДФ='д ММММ'")); // АПК:1367 
	
КонецФункции   

&НаКлиентеНаСервереБезКонтекста
Функция ДеньНеделиВФормулировкеСКакогоПереносим(Дата)
	
	Соответствие = Новый Соответствие;
	Соответствие.Вставить(1, НСтр("ru = 'понедельника'"));
	Соответствие.Вставить(2, НСтр("ru = 'вторника'"));
	Соответствие.Вставить(3, НСтр("ru = 'среды'"));
	Соответствие.Вставить(4, НСтр("ru = 'четверга'"));
	Соответствие.Вставить(5, НСтр("ru = 'пятницы'"));
	Соответствие.Вставить(6, НСтр("ru = 'субботы'"));
	Соответствие.Вставить(7, НСтр("ru = 'воскресенья'"));
	
	Представление = Соответствие[ДеньНедели(Дата)];
	Если Представление = Неопределено Тогда
		Возврат Формат(Дата, "ДФ='дддд'"); // АПК:1367 В данном случае отображение дня недели будет корректным с учетом локализации
	КонецЕсли;
	
	Возврат Представление;
	
КонецФункции

&НаКлиентеНаСервереБезКонтекста
Функция ДеньНеделиВФормулировкеНаКакойПереносим(Дата)
	
	Соответствие = Новый Соответствие;
	Соответствие.Вставить(1, НСтр("ru = 'понедельник'"));
	Соответствие.Вставить(2, НСтр("ru = 'вторник'"));
	Соответствие.Вставить(3, НСтр("ru = 'среду'"));
	Соответствие.Вставить(4, НСтр("ru = 'четверг'"));
	Соответствие.Вставить(5, НСтр("ru = 'пятницу'"));
	Соответствие.Вставить(6, НСтр("ru = 'субботу'"));
	Соответствие.Вставить(7, НСтр("ru = 'воскресенье'"));
	
	Представление = Соответствие[ДеньНедели(Дата)];
	Если Представление = Неопределено Тогда
		Возврат Формат(Дата, "ДФ='дддд'"); // АПК:1367 В данном случае отображение дня недели будет корректным с учетом локализации
	КонецЕсли;
	
	Возврат Представление;
	
КонецФункции

&НаКлиентеНаСервереБезКонтекста
Процедура УстановитьВидимостьСпискаПереносов(Форма)
	
	ВидимостьСписка = Форма.СписокПереносов.Количество() > 0;
	ОбщегоНазначенияКлиентСервер.УстановитьСвойствоЭлементаФормы(Форма.Элементы, "СписокПереносов", "Видимость", ВидимостьСписка);
	
КонецПроцедуры

&НаСервере
Процедура УстановитьДоступностьУчитыватьПраздники()
	
	Элементы.УчитыватьПраздничныеДни.Доступность = ЗначениеЗаполнено(Объект.ПроизводственныйКалендарь);
	Если Не Элементы.УчитыватьПраздничныеДни.Доступность Тогда
		Объект.УчитыватьПраздничныеДни = Ложь;
	КонецЕсли;
	
КонецПроцедуры

&НаСервере
Процедура ПрочитатьНерабочиеДаты(ТекущийОбъект = Неопределено)
	
	Если ТекущийОбъект = Неопределено Тогда
		ТекущийОбъект = Объект;
	КонецЕсли;
	
	Даты = Новый Массив;
	
	ПроизводственныйКалендарь = ?(ЗначениеЗаполнено(Объект.БазовыйКалендарь), 
	ТекущийОбъект.БазовыйКалендарь, ТекущийОбъект.Ссылка);
	
	Если ЗначениеЗаполнено(ПроизводственныйКалендарь) Тогда
		Периоды = РегистрыСведений.КалендарныеГрафики.ПериодыНерабочихДней(
		ПроизводственныйКалендарь, Новый СтандартныйПериод(Дата(НомерТекущегоГода, 1, 1), Дата(НомерТекущегоГода, 12, 31)), Объект.Код);
		Пояснение = "";
		Для Каждого ОписаниеПериода Из Периоды Цикл
			ОбщегоНазначенияКлиентСервер.ДополнитьМассив(Даты, ОписаниеПериода.Даты);
			Пояснение = Пояснение + ?(Не ПустаяСтрока(Пояснение), Символы.ПС, "") + ОписаниеПериода.Представление;
		КонецЦикла;
		Элементы.НерабочиеПериодыТекст.Заголовок = Пояснение;
	КонецЕсли;
	
	НерабочиеДаты = Новый ФиксированныйМассив(Даты);
	Элементы.НерабочиеПериодыГруппа.Видимость = НерабочиеДаты.Количество() > 0;
	
КонецПроцедуры  

&НаСервере
Процедура НастроитьПолеКалендаря()
	Если ЗначениеЗаполнено(Объект.Год) Тогда
		НомерТекущегоГода = Объект.Год;	
	ИначеЕсли НомерТекущегоГода = 0 Тогда
		НомерТекущегоГода = Год(ТекущаяДатаСеанса());
	КонецЕсли;
	НомерПредыдущегоГода = НомерТекущегоГода;
	
	Элементы.Календарь.НачалоПериодаОтображения	= Дата(НомерТекущегоГода, 1, 1);
	Элементы.Календарь.КонецПериодаОтображения	= Дата(НомерТекущегоГода, 12, 31);
	
	Объект.ДатаНачала = Дата(НомерТекущегоГода, 1, 1);
	Объект.ДатаОкончания = Дата(НомерТекущегоГода, 12, 31);
	Объект.Год = НомерТекущегоГода; 
	
КонецПроцедуры


&НаСервере
Процедура  ЗаполнитьСписокВидовДня()
	
	Для Каждого МетаданныеВидаДней Из Метаданные.Перечисления.ВидыДнейПроизводственногоКалендаря.ЗначенияПеречисления Цикл
		СписокВидовДня.Добавить(Перечисления.ВидыДнейПроизводственногоКалендаря[МетаданныеВидаДней.Имя], МетаданныеВидаДней.Синоним);
	КонецЦикла;
	
КонецПроцедуры 


&НаСервере
Процедура ЗаполнитьЦветаВидовДней ()
	
	ЦветаОформления = Новый Соответствие;
	
	ЦветаОформления.Вставить(Перечисления.ВидыДнейПроизводственногоКалендаря.Рабочий,				WebЦвета.Черный);
	ЦветаОформления.Вставить(Перечисления.ВидыДнейПроизводственногоКалендаря.Суббота,				WebЦвета.ТемноКрасный);
	ЦветаОформления.Вставить(Перечисления.ВидыДнейПроизводственногоКалендаря.Воскресенье,			WebЦвета.Красный);
	ЦветаОформления.Вставить(Перечисления.ВидыДнейПроизводственногоКалендаря.Предпраздничный,	WebЦвета.ТемноСиний);
	ЦветаОформления.Вставить(Перечисления.ВидыДнейПроизводственногоКалендаря.Праздник,				WebЦвета.Фиолетовый);
	
	ЦветаВидовДней = Новый ФиксированноеСоответствие(ЦветаОформления);
	
КонецПроцедуры   


&НаСервере
Процедура СформироватьШаблонРасписания ()
	Если Объект.РабочиеДни.Количество() > 0 Тогда
		Возврат;
	КонецЕсли;

	ШаблонЗаполнения = Новый Массив;
	ШаблонЗаполнения.Добавить(НСтр("ru = 'Понедельник'"));
	ШаблонЗаполнения.Добавить(НСтр("ru = 'Вторник'"));
	ШаблонЗаполнения.Добавить(НСтр("ru = 'Среда'"));
	ШаблонЗаполнения.Добавить(НСтр("ru = 'Четверг'"));
	ШаблонЗаполнения.Добавить(НСтр("ru = 'Пятница'"));
	ШаблонЗаполнения.Добавить(НСтр("ru = 'Суббота'"));
	ШаблонЗаполнения.Добавить(НСтр("ru = 'Воскресенье'"));
	
	Для Каждого СтрДень Из ШаблонЗаполнения Цикл
		ДобСтрДень = Объект.РабочиеДни.Добавить();
		ДобСтрДень.ДеньВключенВГрафик = (СтрДень <> "Суббота" И СтрДень <> "Воскресенье");
		ДобСтрДень.ДеньНедели = СтрДень;
	КонецЦикла;
		
КонецПроцедуры   


&НаКлиенте
Процедура РабочиеДниПредставлениеРасписанияНажатие(Элемент, СтандартнаяОбработка)
	СтандартнаяОбработка = Ложь;
КонецПроцедуры 

&НаСервере
Процедура УстановитьУсловноеОформление()
	
	УсловноеОформление.Элементы.Очистить();
	
	Элемент = УсловноеОформление.Элементы.Добавить();
	
	ПолеЭлемента = Элемент.Поля.Элементы.Добавить();
	ПолеЭлемента.Поле = Новый ПолеКомпоновкиДанных(Элементы.РабочиеДниПредставлениеРасписания.Имя);
	
	ОтборЭлемента = Элемент.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
	ОтборЭлемента.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Объект.РабочиеДни.ПредставлениеРасписания");
	ОтборЭлемента.ВидСравнения = ВидСравненияКомпоновкиДанных.НеЗаполнено;
	
	Элемент.Оформление.УстановитьЗначениеПараметра("Текст", НСтр("ru = 'Заполнить расписание'"));
	
КонецПроцедуры


&НаКлиенте
Процедура РабочиеДниВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	СтрокаШаблона = Объект.РабочиеДни.НайтиПоИдентификатору(ВыбраннаяСтрока);
	Если СтрокаШаблона <> Неопределено Тогда
		НачатьЗаполнениеРасписанияДня(СтрокаШаблона.НомерСтроки, ВыбраннаяСтрока);
	КонецЕсли;

КонецПроцедуры 

&НаКлиенте
Процедура НачатьЗаполнениеРасписанияДня(НомерДня, ИдентификаторСтрокиШаблона = Неопределено)
	
	КонтекстВыбора = Новый Структура("НомерДня, ИдентификаторСтрокиШаблона", НомерДня, ИдентификаторСтрокиШаблона);
	
	//ПереходящиеСмены = Объект.СпособЗаполнения = ПредопределенноеЗначение(
	//	"Перечисление.СпособыЗаполненияГрафикаРаботы.ПоЦикламПроизвольнойДлины");
	
	ПараметрыФормы = Новый Структура;
	ПараметрыФормы.Вставить("РасписаниеРаботы", РасписаниеРаботы(КонтекстВыбора.НомерДня));
	//ПараметрыФормы.Вставить("ПереходящиеСмены", ПереходящиеСмены);
	ПараметрыФормы.Вставить("ТолькоПросмотр", ТолькоПросмотр);
	
	ОбработчикЗакрытия = Новый ОписаниеОповещения("ЗавершитьЗаполнениеРасписанияДня", ЭтотОбъект, КонтекстВыбора);
	ОткрытьФорму("Справочник.ГрафикРаботы.Форма.РасписаниеРаботы", ПараметрыФормы, ЭтотОбъект, , , , ОбработчикЗакрытия);
	
КонецПроцедуры     

// Не было
&НаКлиенте
Функция ПолучитьРасписаниеРаботыДня(НомерДня)
	
	РасписаниеДня = Новый Массив;
	Для Каждого СтрокаРасписания Из Объект.РасписаниеРаботы Цикл
		Если СтрокаРасписания.НомерДня = НомерДня Тогда
			РасписаниеДня.Добавить(Новый Структура("ВремяНачала, ВремяОкончания", СтрокаРасписания.ВремяНачала, СтрокаРасписания.ВремяОкончания));
		КонецЕсли;
	КонецЦикла;
	
	Возврат РасписаниеДня;
	
КонецФункции

&НаКлиенте
Функция РасписаниеРаботы(НомерДня)
	
	РасписаниеДня = Новый Массив;
	
	Для Каждого СтрокаРасписания Из Объект.РасписаниеРаботы Цикл
		Если СтрокаРасписания.НомерДня = НомерДня Тогда
			РасписаниеДня.Добавить(Новый Структура("ВремяНачала, ВремяОкончания", СтрокаРасписания.ВремяНачала, СтрокаРасписания.ВремяОкончания));
		КонецЕсли;
	КонецЦикла;
	
	Возврат РасписаниеДня;
	
КонецФункции

&НаКлиенте
Процедура ЗавершитьЗаполнениеРасписанияДня(ВыбранноеЗначение, КонтекстВыбора) Экспорт
	
	Если ВыбранноеЗначение = Неопределено Или ТолькоПросмотр Тогда
		Возврат;
	КонецЕсли;
	
	// Удаляем ранее заполненное расписания для этого дня.
	СтрокиДня = Новый Массив;
	Для Каждого СтрокаРасписания Из Объект.РасписаниеРаботы Цикл
		Если СтрокаРасписания.НомерДня = КонтекстВыбора.НомерДня Тогда
			СтрокиДня.Добавить(СтрокаРасписания.ПолучитьИдентификатор());
		КонецЕсли;
	КонецЦикла;
	Для Каждого ИдентификаторСтроки Из СтрокиДня Цикл
		Объект.РасписаниеРаботы.Удалить(Объект.РасписаниеРаботы.НайтиПоИдентификатору(ИдентификаторСтроки));
	КонецЦикла;
	
	// Заполняем расписание работы на день.
	Для Каждого ОписаниеИнтервала Из ВыбранноеЗначение.РасписаниеРаботы Цикл
		НоваяСтрока = Объект.РасписаниеРаботы.Добавить();
		ЗаполнитьЗначенияСвойств(НоваяСтрока, ОписаниеИнтервала);
		НоваяСтрока.НомерДня = КонтекстВыбора.НомерДня;
	КонецЦикла;
		
	//УстановитьСнятьПризнакСоответствияРезультатовШаблону(ЭтотОбъект, Ложь);
	//УстановитьСнятьМодифицированностьШаблона(ЭтотОбъект, Истина);
	
	Если КонтекстВыбора.ИдентификаторСтрокиШаблона <> Неопределено Тогда
		СтрокаШаблона = Объект.РабочиеДни.НайтиПоИдентификатору(КонтекстВыбора.ИдентификаторСтрокиШаблона);
		Если СтрокаШаблона <> Неопределено Тогда
			СтрокаШаблона.ДеньВключенВГрафик = (ВыбранноеЗначение.РасписаниеРаботы.Количество() > 0);
			СтрокаШаблона.ПредставлениеРасписания = ПредставлениеРасписанияДня(КонтекстВыбора.НомерДня);
		КонецЕсли;
	КонецЕсли; 
	
	//ЗаполнитьПоШаблонуНаСервере();
	
КонецПроцедуры 


&НаКлиенте
Функция ПредставлениеРасписанияДня(НомерДня)	
	ПредставлениеИнтервалов = "";
	Секунд = 0;
	Для Каждого СтрокаРасписания Из Объект.РасписаниеРаботы Цикл
		Если СтрокаРасписания.НомерДня <> НомерДня Тогда
			Продолжить;
		КонецЕсли;
		ПредставлениеИнтервала = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
			"%1-%2, ", 
			ПредставлениеВремениСуток(СтрокаРасписания.ВремяНачала, ДвенадцатиЧасовойФорматВремени), 
			ПредставлениеВремениСуток(СтрокаРасписания.ВремяОкончания, ДвенадцатиЧасовойФорматВремени)
		);
		ПредставлениеИнтервалов = ПредставлениеИнтервалов + ПредставлениеИнтервала;
		
		Если СтрокаРасписания.ВремяНачала = СтрокаРасписания.ВремяОкончания Тогда
			СекундИнтервала = 86400;
		ИначеЕсли СтрокаРасписания.ВремяНачала < СтрокаРасписания.ВремяОкончания Тогда
			СекундИнтервала = СтрокаРасписания.ВремяОкончания - СтрокаРасписания.ВремяНачала;
		ИначеЕсли Не ЗначениеЗаполнено(СтрокаРасписания.ВремяОкончания) Тогда
			СекундИнтервала = КонецДня(СтрокаРасписания.ВремяОкончания) - СтрокаРасписания.ВремяНачала + 1;
		Иначе
			ОсновнаяЧасть = КонецДня(СтрокаРасписания.ВремяНачала) - СтрокаРасписания.ВремяНачала + 1;
			ПереходящаяЧасть = СтрокаРасписания.ВремяОкончания - НачалоДня(СтрокаРасписания.ВремяОкончания);
			СекундИнтервала = ОсновнаяЧасть + ПереходящаяЧасть;
		КонецЕсли;
		Секунд = Секунд + СекундИнтервала;
	КонецЦикла;
	СтроковыеФункцииКлиентСервер.УдалитьПоследнийСимволВСтроке(ПредставлениеИнтервалов, 2);
	
	Если Секунд = 0 Тогда
		Возврат НСтр("ru = 'Заполнить расписание'");
	КонецЕсли;
	
	Часов = Окр(Секунд / 3600, 1);
	
	Возврат СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(НСтр("ru = '%1 ч. (%2)'"), Часов, ПредставлениеИнтервалов);
	
КонецФункции

&НаКлиентеНаСервереБезКонтекста
Функция ПредставлениеВремениСуток(Знач ВремяСуток, ДвенадцатиЧасовойФорматВремени)
	
	Если Не ЗначениеЗаполнено(ВремяСуток) Тогда
		ВремяСуток = Дата(1980, 1, 1);
	КонецЕсли;
	
	ФорматВремени = ?(ДвенадцатиЧасовойФорматВремени,
	НСтр("ru = 'ДФ=''чч:мм вв'''"), НСтр("ru = 'ДФ=ЧЧ:мм; ДП='"));
	
	Возврат Формат(ВремяСуток, ФорматВремени);
	
КонецФункции


&НаСервере
Процедура ЗаполнитьСписокЗначенийПроизводственныйКалендарьНаСервере()
	
	ТаблицаПроизводственныхКалендарей = Справочники.ГрафикРаботы.ПолучитьТаблицуПроизводственныхКалендарей(); 
	Для Каждого Стр Из ТаблицаПроизводственныхКалендарей Цикл
		Элементы.ПроизводственныйКалендарь.СписокВыбора.Добавить(Стр.code, Стр.Description);
	КонецЦикла;	
	
КонецПроцедуры

&НаКлиенте
Процедура ПроизводственныйКалендарьПриИзменении(Элемент)
	
	ЗаполнитьДаннымиПоУмолчанию(); 
	
	ПроизводственныйКалендарьПриИзмененииНаСервере();
	
	Элементы.Календарь.Обновить();
	
КонецПроцедуры 

&НаСервере
Процедура ПроизводственныйКалендарьПриИзмененииНаСервере()

	УстановитьДоступностьУчитыватьНерабочиеПериоды(); 
	
	УстановитьДоступностьУчитыватьПраздники(); 
	
КонецПроцедуры

&НаКлиенте
Процедура ИзменитьДень(Команда)
	
	ВыделенныеДаты = Элементы.Календарь.ВыделенныеДаты;
	
	Если ВыделенныеДаты.Количество() > 0 И Год(ВыделенныеДаты[0]) = НомерТекущегоГода Тогда
		Оповещение = Новый ОписаниеОповещения("ИзменитьДеньЗавершение", ЭтотОбъект, ВыделенныеДаты);
		ПоказатьВыборИзСписка(Оповещение, СписокВидовДня, , СписокВидовДня.НайтиПоЗначению(ВидыДней.Получить(ВыделенныеДаты[0])));
	КонецЕсли;
	
КонецПроцедуры  


&НаКлиенте
Процедура ИзменитьДеньЗавершение(ВыбранныйЭлемент, ВыделенныеДаты) Экспорт
	
	Если ВыбранныйЭлемент <> Неопределено Тогда
		ИзменитьВидыДней(ВыделенныеДаты, ВыбранныйЭлемент.Значение);
		Элементы.Календарь.Обновить();
	КонецЕсли;
	
КонецПроцедуры 

&НаКлиенте
Процедура ИзменитьВидыДней(ДатыДней, ВидДня)
	
	// Устанавливает дням по всем датам массива определенный вид.
	
	ВидыДнейСоответствие = Новый Соответствие(ВидыДней);
	
	Для Каждого ВыбраннаяДата Из ДатыДней Цикл
		ВидыДнейСоответствие.Вставить(ВыбраннаяДата, ВидДня);
	КонецЦикла;
	
	ВидыДней = Новый ФиксированноеСоответствие(ВидыДнейСоответствие);
	
КонецПроцедуры 


&НаКлиенте
Процедура КалендарьПриВыводеПериода(Элемент, ОформлениеПериода)
	
	Для Каждого СтрокаОформленияПериода Из ОформлениеПериода.Даты Цикл
		ЦветОформленияДня = ЦветаВидовДней.Получить(ВидыДней.Получить(СтрокаОформленияПериода.Дата));
		Если ДниГрафика.Получить(СтрокаОформленияПериода.Дата)  <> Неопределено Тогда
			ЦветФонаДня = WebЦвета.Роса;
		Иначе
			ЦветФонаДня = WebЦвета.Белый;
		КонецЕсли;	
		Если ЦветОформленияДня = Неопределено Тогда
			ЦветОформленияДня = WebЦвета.Красный;
		КонецЕсли;
		СтрокаОформленияПериода.ЦветТекста = ЦветОформленияДня;
		СтрокаОформленияПериода.ЦветФона = ЦветФонаДня;
		Если НерабочиеДаты.Найти(СтрокаОформленияПериода.Дата) <> Неопределено Тогда
			СтрокаОформленияПериода.ЦветФона = WebЦвета.Фиолетовый;
		КонецЕсли; 
	КонецЦикла; 
	
КонецПроцедуры



&НаСервере
Процедура ПриЗаписиНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)
	
	НомерГода = НомерТекущегоГода;
	Если ПараметрыЗаписи.Свойство("НомерГода") И ЗначениеЗаполнено(ПараметрыЗаписи.НомерГода) Тогда
		НомерГода = ПараметрыЗаписи.НомерГода;
	КонецЕсли; 
		
	ЗаписатьДанныеПроизводственногоКалендаряНаСервере(НомерГода, ТекущийОбъект); 
	
	РегистрыСведений.КалендарныеГрафики.ЗаписатьДанныеГрафикаВРегистр(ТекущийОбъект.Ссылка, ДниГрафика, 
	Дата(НомерГода, 1, 1), Дата(НомерГода, 12, 31), Истина);

	
КонецПроцедуры 


&НаСервере
Процедура ЗаписатьДанныеПроизводственногоКалендаряНаСервере(Знач НомерГода, Знач ТекущийОбъект = Неопределено)
	
	// Запись данных производственного календаря за указанный год.
		
	ДанныеПроизводственногоКалендаря = Новый ТаблицаЗначений;
	ДанныеПроизводственногоКалендаря.Колонки.Добавить("Дата", Новый ОписаниеТипов("Дата"));
	ДанныеПроизводственногоКалендаря.Колонки.Добавить("ВидДня", Новый ОписаниеТипов("ПеречислениеСсылка.ВидыДнейПроизводственногоКалендаря"));
	ДанныеПроизводственногоКалендаря.Колонки.Добавить("ДатаПереноса", Новый ОписаниеТипов("Дата"));
	
	Для Каждого КлючИЗначение Из ВидыДней Цикл
		
		СтрокаТаблицы = ДанныеПроизводственногоКалендаря.Добавить();
		СтрокаТаблицы.Дата = КлючИЗначение.Ключ;
		СтрокаТаблицы.ВидДня = КлючИЗначение.Значение;
		
		// Если день перенесен с другой даты, вписываем дату переноса.
		ДатаПереноса = ПереносыДней.Получить(СтрокаТаблицы.Дата);
		Если ДатаПереноса <> Неопределено И ДатаПереноса <> СтрокаТаблицы.Дата Тогда
			СтрокаТаблицы.ДатаПереноса = ДатаПереноса;
		КонецЕсли;
		
	КонецЦикла;
	
	Справочники.ГрафикРаботы.ЗаписатьДанныеПроизводственногоКалендаря(ТекущийОбъект.Ссылка, НомерГода, ДанныеПроизводственногоКалендаря);
	
КонецПроцедуры  


&НаСервере
Процедура ПриЧтенииНаСервере(ТекущийОбъект)
	НомерТекущегоГода = ТекущийОбъект.Год;
	ЗаполнитьДаннымиТекущегоГода();
КонецПроцедуры

&НаКлиенте
Процедура НомерТекущегоГодаПриИзменении(Элемент)
	ЗаписыватьДанныеГрафика = Ложь; 
	Если Модифицированность Тогда
		ТекстСообщения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(НСтр("ru = 'Записать измененные данные за %1 год?'"), Формат(НомерТекущегоГода, "ЧГ=0"));
		Оповещение = Новый ОписаниеОповещения("НомерТекущегоГодаПриИзмененииЗавершение", ЭтотОбъект);
		ПоказатьВопрос(Оповещение, ТекстСообщения, РежимДиалогаВопрос.ДаНет);
		Возврат;
	КонецЕсли;
	
	ОбработатьИзменениеГода(ЗаписыватьДанныеГрафика); 
	
	Если ЗначениеЗаполнено(Объект.ПроизводственныйКалендарь) Тогда
		ЗаполнитьДаннымиПоУмолчанию();
	КонецЕсли;
	
	Модифицированность = Ложь;
	
	Элементы.Календарь.Обновить(); 
	
КонецПроцедуры  

&НаСервере
Процедура ОбработатьИзменениеГода(ЗаписыватьДанныеГрафика)
	
	Если Не ЗаписыватьДанныеГрафика Тогда
		ЗаполнитьДаннымиТекущегоГода();
		Возврат;
	КонецЕсли;
	
	Если Объект.Ссылка.Пустая() Тогда
		Записать(Новый Структура("НомерГода", НомерТекущегоГода));
	Иначе
		ЗаписатьДанныеПроизводственногоКалендаряНаСервере(НомерТекущегоГода, РеквизитФормыВЗначение("Объект"));
	КонецЕсли;
	
	ЗаполнитьДаннымиТекущегоГода();	
	
КонецПроцедуры  

&НаКлиенте
Процедура НомерТекущегоГодаПриИзмененииЗавершение(Ответ, ДополнительныеПараметры) Экспорт
	
	ОбработатьИзменениеГода(Ответ = КодВозвратаДиалога.Да);
	Модифицированность = Ложь;
	Элементы.Календарь.Обновить();
	
КонецПроцедуры

//&НаКлиенте
//Процедура ПеренестиДень(Команда)
//	ВыделенныеДаты = Элементы.Календарь.ВыделенныеДаты;
//	
//	Если ВыделенныеДаты.Количество() = 0 Или Год(ВыделенныеДаты[0]) <> НомерТекущегоГода Тогда
//		Возврат;
//	КонецЕсли;
//	
//	ДатаПереноса = ВыделенныеДаты[0];
//	ВидДня = ВидыДней.Получить(ДатаПереноса);
//	
//	ПараметрыВыбораДаты = Новый Структура(
//	"НачальноеЗначение, 
//	|НачалоПериодаОтображения, 
//	|КонецПериодаОтображения, 
//	|Заголовок, 
//	|ПоясняющийТекст");
//	
//	ПараметрыВыбораДаты.НачальноеЗначение = ДатаПереноса;
//	ПараметрыВыбораДаты.НачалоПериодаОтображения = НачалоГода(Календарь);
//	ПараметрыВыбораДаты.КонецПериодаОтображения = КонецГода(Календарь);
//	ПараметрыВыбораДаты.Заголовок = НСтр("ru = 'Выбор даты переноса'");
//	
//	ПараметрыВыбораДаты.ПоясняющийТекст = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
//	НСтр("ru = 'Выберите дату, на которую будет осуществлен перенос дня %1 (%2)'"), 
//	Формат(ДатаПереноса, "ДФ='д ММММ'"), // АПК:1367 Хорошего решения нет, считаем сохранение порядка дата + месяц приемлемым решением в этом месте
//	ВидДня);
//	
//	ОткрытьФорму("Справочник.ГрафикРаботы.Форма.ВыборДаты", ПараметрыВыбораДаты, ЭтотОбъект);
//КонецПроцедуры 

// Проверить
&НаКлиенте
Процедура ПеренестиДень(Команда)
	
	ВыделенныеДаты = Элементы.Календарь.ВыделенныеДаты;
	Если ВыделенныеДаты.Количество() = 0 Или Год(ВыделенныеДаты[0]) <> НомерТекущегоГода Тогда
		Возврат;
	КонецЕсли;
	
	ДатаПереноса = ВыделенныеДаты[0];
	
	ПараметрыВыбораДаты = Новый Структура;
	ПараметрыВыбораДаты.Вставить("НачальноеЗначение", ДатаПереноса);
	ПараметрыВыбораДаты.Вставить("НачалоПериодаОтображения", НачалоГода(ДатаПереноса));
	ПараметрыВыбораДаты.Вставить("КонецПериодаОтображения", КонецГода(ДатаПереноса));
	ПараметрыВыбораДаты.Вставить("Заголовок", НСтр("ru = 'Выбор даты переноса'"));
	ПараметрыВыбораДаты.Вставить("ПоясняющийТекст", СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
		НСтр("ru = 'Выберите дату, на которую переносится %1'"), 
		Формат(ДатаПереноса, "ДФ='д ММММ'")
	));
	
	Оповещение = Новый ОписаниеОповещения("ПеренестиДеньЗавершение", ЭтотОбъект, ДатаПереноса);
	ОткрытьФорму("Справочник.ГрафикРаботы.Форма.ВыборДаты", ПараметрыВыбораДаты, ЭтотОбъект, , , , Оповещение);
	
КонецПроцедуры 

// Не было
&НаКлиенте
Процедура ПеренестиДеньЗавершение(ВыбраннаяДата, ДатаПереноса) Экспорт
	
	Если ЗначениеЗаполнено(ВыбраннаяДата) И ВыбраннаяДата <> ДатаПереноса Тогда
		ПереносыДнейСоответствие = Новый Соответствие(ПереносыДней);
		ПереносыДнейСоответствие.Вставить(ДатаПереноса, ВыбраннаяДата);
		ПереносыДней = Новый ФиксированноеСоответствие(ПереносыДнейСоответствие);
		
		ЗаполнитьПредставлениеПереносовНаКлиенте();
		Элементы.Календарь.Обновить();
	КонецЕсли;
	
КонецПроцедуры

// Не было
&НаКлиенте
Процедура ЗаполнитьПредставлениеПереносовНаКлиенте()
	
	СписокПереносов.Очистить();
	Для Каждого КлючИЗначение Из ПереносыДней Цикл
		ДатаИсточник = КлючИЗначение.Ключ;
		ДатаПриемник = КлючИЗначение.Значение;
		ВидДня = ВидыДней.Получить(ДатаИсточник);
		
		Если ВидДня = ПредопределенноеЗначение("Перечисление.ВидыДнейПроизводственногоКалендаря.Суббота")
			Или ВидДня = ПредопределенноеЗначение("Перечисление.ВидыДнейПроизводственногоКалендаря.Воскресенье") Тогда
			ДатаПереноса = ДатаПриемник;
			ДатаПриемник = ДатаИсточник;
			ДатаИсточник = ДатаПереноса;
		КонецЕсли;
		
		Если СписокПереносов.НайтиПоЗначению(ДатаИсточник) <> Неопределено 
			Или СписокПереносов.НайтиПоЗначению(ДатаПриемник) <> Неопределено Тогда
			Продолжить;
		КонецЕсли;
		
		СписокПереносов.Добавить(ДатаИсточник, ПредставлениеПереноса(ДатаИсточник, ДатаПриемник));
	КонецЦикла;
	
	СписокПереносов.СортироватьПоЗначению();
	Элементы.СписокПереносов.Видимость = (СписокПереносов.Количество() > 0);
	
КонецПроцедуры

&НаКлиенте
Процедура ОбработкаВыбора(ВыбранноеЗначение, ИсточникВыбора)
	Если ВРег(ИсточникВыбора.ИмяФормы) = ВРег("Справочник.ГрафикРаботы.Форма.ВыборДаты") Тогда
		Если ВыбранноеЗначение = Неопределено Тогда
			Возврат;
		КонецЕсли;
		ВыделенныеДаты = Элементы.Календарь.ВыделенныеДаты;
		Если ВыделенныеДаты.Количество() = 0 Или Год(ВыделенныеДаты[0]) <> НомерТекущегоГода Тогда
			Возврат;
		КонецЕсли;
		ДатаПереноса = ВыделенныеДаты[0];
		ПеренестиВидДня(ДатаПереноса, ВыбранноеЗначение);
		Элементы.Календарь.Обновить();
	КонецЕсли;
КонецПроцедуры

&НаКлиенте
Процедура ПеренестиВидДня(ДатаПереноса, ДатаНазначения)
	
	// Нужно обменять местами два дня в календаре
	// - обменяться видами дня
	// - запомнить даты переноса
	//	* если переносимый день уже имеет дату переноса (уже был откуда-то перенесен), 
	//		используем имеющуюся дату переноса
	//	* если даты совпадают (день возвращен на "свое место") - удаляем такую запись.
	
	ВидыДнейСоответствие = Новый Соответствие(ВидыДней);
	
	ВидыДнейСоответствие.Вставить(ДатаНазначения, ВидыДней.Получить(ДатаПереноса));
	ВидыДнейСоответствие.Вставить(ДатаПереноса, ВидыДней.Получить(ДатаНазначения));
	
	ПереносыДнейСоответствие = Новый Соответствие(ПереносыДней);
	
	ВписатьДатуПереноса(ПереносыДнейСоответствие, ДатаПереноса, ДатаНазначения);
	ВписатьДатуПереноса(ПереносыДнейСоответствие, ДатаНазначения, ДатаПереноса);
	
	ВидыДней = Новый ФиксированноеСоответствие(ВидыДнейСоответствие);
	ПереносыДней = Новый ФиксированноеСоответствие(ПереносыДнейСоответствие);
	
	ЗаполнитьПредставлениеПереносов(ЭтотОбъект);
	
КонецПроцедуры   

&НаКлиенте
Процедура ВписатьДатуПереноса(ПереносыДнейСоответствие, ДатаПереноса, ДатаНазначения)
	
	// Заполняет в соответствии с датами переносов дней корректную дату переноса.
	
	ИсточникДняДатыНазначения = ПереносыДней.Получить(ДатаНазначения);
	Если ИсточникДняДатыНазначения = Неопределено Тогда
		ИсточникДняДатыНазначения = ДатаНазначения;
	КонецЕсли;
	
	Если ДатаПереноса = ИсточникДняДатыНазначения Тогда
		ПереносыДнейСоответствие.Удалить(ДатаПереноса);
	Иначе	
		ПереносыДнейСоответствие.Вставить(ДатаПереноса, ИсточникДняДатыНазначения);
	КонецЕсли;
	
КонецПроцедуры

&НаКлиенте
Процедура УчитыватьПраздничныеДниПриИзменении(Элемент)
	
	//ЗаполнитьПоШаблонуНаСервере(); 
	//
	//Элементы.Календарь.Обновить(); 
	
КонецПроцедуры

&НаСервере
Процедура ЗаполнитьПоШаблонуНаСервере(СохранятьРучноеРедактирование = Ложь)
	
	ПараметрыЗаполнения = РегистрыСведений.КалендарныеГрафики.ПараметрыЗаполненияГрафика();
	ПараметрыЗаполнения.КодПроизводственногоКалендаря = Объект.Код;
	//ПараметрыЗаполнения.СпособЗаполнения = Объект.СпособЗаполнения;
	ПараметрыЗаполнения.ШаблонЗаполнения = Объект.РабочиеДни;
	ПараметрыЗаполнения.ПроизводственныйКалендарь = Объект.Ссылка;
	ПараметрыЗаполнения.УчитыватьПраздники = Объект.УчитыватьПраздничныеДни;
	ПараметрыЗаполнения.УчитыватьНерабочиеПериоды = Объект.УчитыватьНерабочиеПериоды;
	//ПараметрыЗаполнения.ДатаОтсчета = Объект.ДатаОтсчета;
	
	ДниВключенныеВГрафик = РегистрыСведений.КалендарныеГрафики.ДниВключенныеВГрафик(
	Объект.ДатаНачала, Объект.ДатаОкончания, ПараметрыЗаполнения);
	
	//Если РучноеРедактирование Тогда
	//	Если СохранятьРучноеРедактирование Тогда
	//		// Переносим ручные корректировки.
	//		Для Каждого КлючИЗначение Из ДниИзмененные Цикл
	//			ДатаИзменений = КлючИЗначение.Ключ;
	//			ДеньВключенВГрафик = КлючИЗначение.Значение;
	//			Если ДеньВключенВГрафик Тогда
	//				ДниВключенныеВГрафик.Вставить(ДатаИзменений, Истина);
	//			Иначе
	//				ДниВключенныеВГрафик.Удалить(ДатаИзменений);
	//			КонецЕсли;
	//		КонецЦикла;
	//	Иначе
	//		УстановитьСнятьМодифицированностьРезультата(ЭтотОбъект, Истина);
	//		УстановитьСнятьПризнакРучногоРедактирования(ЭтотОбъект, Ложь);
	//	КонецЕсли;
	//КонецЕсли;
	
	// Переносим результат в исходное соответствие заполнения, 
	// чтобы не затереть даты, не входящие в интервал заполнения.
	ДниГрафикаСоответствие = Новый Соответствие(ДниГрафика);
	ДатаДня = Объект.ДатаНачала;
	ДатаОкончания = Объект.ДатаОкончания;
	Если Не ЗначениеЗаполнено(ДатаОкончания) Тогда
		ДатаОкончания = КонецГода(Объект.ДатаНачала);
	КонецЕсли;
	Пока ДатаДня <= ДатаОкончания Цикл
		ДеньВключенВГрафик = ДниВключенныеВГрафик[ДатаДня];
		Если ДеньВключенВГрафик = Неопределено Тогда
			ДниГрафикаСоответствие.Удалить(ДатаДня);
		Иначе
			ДниГрафикаСоответствие.Вставить(ДатаДня, ДеньВключенВГрафик);
		КонецЕсли;
		ДатаДня = ДатаДня + 86400;
	КонецЦикла;
	
	ДниГрафика = Новый ФиксированноеСоответствие(ДниГрафикаСоответствие);
	
	//Если Не РезультатЗаполненПоШаблону Тогда
	//	УстановитьСнятьМодифицированностьРезультата(ЭтотОбъект, Истина);
	//	УстановитьСнятьПризнакСоответствияРезультатовШаблону(ЭтотОбъект, Истина);
	//КонецЕсли;
	
КонецПроцедуры

&НаКлиенте
Процедура РабочиеДниДеньВключенВГрафикПриИзменении(Элемент)

	//ЗаполнитьПоШаблонуНаСервере();

	//Элементы.Календарь.Обновить(); 

КонецПроцедуры

&НаКлиенте
Процедура ЗаполнитьПоШаблону(Команда)
	
	Если ПроверитьЗаполнение() Тогда	
		Если Не ЗначениеЗаполнено(Объект.Ссылка) Тогда
			Оповещение=Новый ОписаниеОповещения("ПослеОтветаНаВопрос", ЭтотОбъект);
			ПоказатьВопрос(Оповещение, "Данные не записанны. Записать?", РежимДиалогаВопрос.ДаНет);
		Иначе
			ЗаполнитьПоШаблонуНаСервере();
			Элементы.Календарь.Обновить();
		КонецЕсли; 
	КонецЕсли;
	
	//ЗаполнитьПоШаблонуНаСервере();
	
	//Элементы.Календарь.Обновить();

КонецПроцедуры   

&НаКлиенте
Процедура ПослеОтветаНаВопрос(Результат, ДопПараметры) Экспорт

	Если Результат = КодВозвратаДиалога.Да Тогда
		Записать();
		ЗаполнитьПоШаблонуНаСервере();
		Элементы.Календарь.Обновить();
	КонецЕсли;

КонецПроцедуры