---

&НаКлиенте
Процедура КалендарьПриВыводеПериода(Элемент, ОформлениеПериода)
	
	Для Каждого СтрокаОформленияПериода Из ОформлениеПериода.Даты Цикл
		
		ВидДня = ВидыДней.Получить(СтрокаОформленияПериода.Дата);
		ЦветОформленияДня = ЦветаВидовДней.Получить(ВидДня);
		
		// Если вид дня не заполнен в соответствии, определяем цвет по календарному дню недели
		Если ЦветОформленияДня = Неопределено Тогда
			ДеньНеделиДаты = ДеньНедели(СтрокаОформленияПериода.Дата);
			Если ДеньНеделиДаты = 6 Тогда
				ЦветОформленияДня = WebЦвета.ТемноКрасный;
			ИначеЕсли ДеньНеделиДаты = 7 Тогда
				ЦветОформленияДня = WebЦвета.Красный;
			Иначе
				ЦветОформленияДня = WebЦвета.Черный;
			КонецЕсли;
		КонецЕсли;
		
		// Подсветка фона для дней, включенных в график
		Если ДниГрафика.Получить(СтрокаОформленияПериода.Дата) <> Неопределено Тогда
			ЦветФонаДня = WebЦвета.Роса;
		Иначе
			ЦветФонаДня = WebЦвета.Белый;
		КонецЕсли;	
		
		СтрокаОформленияПериода.ЦветТекста = ЦветОформленияДня;
		СтрокаОформленияПериода.ЦветФона = ЦветФонаДня;
		
		Если НерабочиеДаты.Найти(СтрокаОформленияПериода.Дата) <> Неопределено Тогда
			СтрокаОформленияПериода.ЦветФона = WebЦвета.Фиолетовый;
		КонецЕсли; 
	КонецЦикла; 
	
КонецПроцедуры