---

ВЫБРАТЬ
	МатериалыИЕдиницы.Материалы КАК Материалы,
	МатериалыИЕдиницы.Единица КАК Единица
ПОМЕСТИТЬ ВТ_МатериалыИЕдиницы
ИЗ
	&МатериалыИЕдиницы КАК МатериалыИЕдиницы
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ПартииТоваров.Номенклатура КАК Номенклатура,
	ПартииТоваров.Партия КАК Партия,
	МИНИМУМ(ПартииТоваров.Период) КАК ДатаПрихода
ПОМЕСТИТЬ ВТ_ДатаПрихода
ИЗ
	РегистрНакопления.ПартииТоваров КАК ПартииТоваров
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_МатериалыИЕдиницы КАК ВТ_МатериалыИЕдиницы
		ПО ПартииТоваров.Номенклатура = ВТ_МатериалыИЕдиницы.Материалы
			И ПартииТоваров.Партия.Единица = ВТ_МатериалыИЕдиницы.Единица
ГДЕ
	ПартииТоваров.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)
	И ПартииТоваров.Организация = &Организация
	И ПартииТоваров.МестоХранения = &МестоХранения
	И НЕ ПартииТоваров.Партия.Маркированный

СГРУППИРОВАТЬ ПО
	ПартииТоваров.Номенклатура,
	ПартииТоваров.Партия
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ПартииТоваровОстатки.Номенклатура КАК Номенклатура,
	ПартииТоваровОстатки.Партия КАК Партия,
	ПартииТоваровОстатки.Партия.Цена КАК Цена,
	ПартииТоваровОстатки.КоличествоОстаток КАК Остаток,
	ПартииТоваровОстатки.Партия.ГоденДо КАК ГоденДо,
	ПартииТоваровОстатки.Партия.Единица КАК ПартияЕдиница
ИЗ
	РегистрНакопления.ПартииТоваров.Остатки(
			&МоментВремени,
			МестоХранения = &МестоХранения
				И Организация = &Организация
				И Номенклатура В
					(ВЫБРАТЬ Т.Материалы ИЗ ВТ_МатериалыИЕдиницы КАК Т)
				И НЕ Партия.Маркированный) КАК ПартииТоваровОстатки
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_МатериалыИЕдиницы КАК ВТ_МатериалыИЕдиницы
		ПО ПартииТоваровОстатки.Номенклатура = ВТ_МатериалыИЕдиницы.Материалы
			И ПартииТоваровОстатки.Партия.Единица = ВТ_МатериалыИЕдиницы.Единица
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_ДатаПрихода КАК ВТ_ДатаПрихода
		ПО ПартииТоваровОстатки.Номенклатура = ВТ_ДатаПрихода.Номенклатура
			И ПартииТоваровОстатки.Партия = ВТ_ДатаПрихода.Партия
ГДЕ
	(ПартииТоваровОстатки.Партия.ГоденДо = ДАТАВРЕМЯ(1, 1, 1)
		ИЛИ ПартииТоваровОстатки.Партия.ГоденДо >= НАЧАЛОПЕРИОДА(&ГоденДо, ДЕНЬ))

УПОРЯДОЧИТЬ ПО
	Номенклатура,
	ВЫБОР
		КОГДА ПартииТоваровОстатки.Партия.ГоденДо = ДАТАВРЕМЯ(1, 1, 1)
			ТОГДА ЕСТЬNULL(ВТ_ДатаПрихода.ДатаПрихода, ДАТАВРЕМЯ(1, 1, 1))
		ИНАЧЕ ПартииТоваровОстатки.Партия.ГоденДо
	КОНЕЦ