---

@echo off
set "CD=%~dp0"
set "CD=%CD:~0,-1%"
:: Для установки с подключенного образа диска от M$ "ProPlus2024Retail.img" или любого другого
:: set "CD=E:"
set arch=x64
set cult=en-us
set ffn=7983bac0-e531-40cf-be00-fd24fe66619c
:: Офисные продукты, которые будут установлены
set products=ProPlus2021Volume.16_en-us_ru-ru_x-none^^^|ProjectPro2021Volume.16_en-us_ru-ru_x-none^^^|VisioPro2021Volume.16_en-us_ru-ru_x-none^^^|ProofingTools.16_en-us_ru-ru.proof_x-none
:: Приложения которые устанавливать не хотите
set "productexclusion="
set "pkeys=KNH8D-FGHT4-T8RK3-CTDYJ-K2HT4,FTNWT-C6WBT-8HMGF-K9PRX-QV9H8,FXYTK-NJJ8C-GB6DW-3DYQT-6F7TH"
::-----------------------------------------------------------------------------------------------------------------
set "inst=i320.cab"
If "%PROCESSOR_ARCHITECTURE%"== "AMD64" set "inst=i640.cab"
set "OPath=%ProgramFiles%\Common Files\microsoft shared"

::----------------------Проверка на запуск установки с правами администратора--------------------------------------
>nul 2>&1 net session
if %errorlevel% neq 0 (
    echo Restart with administrator privileges...
    powershell -Command "Start-Process '%~f0' -Verb RunAs"
    exit
)
::-----------------------------------------------------------------------------------------------------------------

cd /d %CD%\
if exist Office for /f %%a in ('dir office\data\* /b/ad') do set ver=%%a
if not defined ver echo AvailableBuild not found& pause& goto :eof
echo Required version: %ver%

IF EXIST "%OPath%\ClickToRun" (
 sc.exe stop ClickToRunSvc >nul 2>&1
 taskkill.exe /t /f /IM OfficeClickToRun.exe >nul 2>&1
 taskkill.exe /t /f /IM IntegratedOffice.exe >nul 2>&1
 taskkill.exe /t /f /IM OfficeC2RClient.exe >nul 2>&1
 
 rd /Q /S "%OPath%\ClickToRun" >nul 2>&1
 
)

mkdir "%OPath%" >nul 2>&1
mkdir "%OPath%\ClickToRun" >nul 2>&1

expand "%CD%\Office\Data\%ver%\%inst%" -F:* "%OPath%\ClickToRun" >nul 2>&1

START /min /D "%OPath%\ClickToRun" "" "%OPath%\ClickToRun\OfficeClickToRun.exe" platform=%arch% culture=%cult% productstoadd=%products% ^
%productexclusion% cdnbaseurl.16=http://officecdn.microsoft.com/pr/%ffn% baseurl.16="%CD%" version.16=%ver% ^
mediatype.16=Local sourcetype.16=Local updatesenabled.16=True autoactivate=1 acceptalleulas.16=True ^
displaylevel=True bitnessmigration=False deliverymechanism=%ffn% pidkeys=%pkeys%